新しいlifted-asyncの使い方

monad-controlが新しくなって、モナド変換子スタックの各層がもつ状態を表すStTやStMがassociated data typesからassociated type synonymsに変わった。この変更でmonad-controlに依存するたくさんのパッケージが壊れ、拙作lifted-asyncも漏れなく壊れた。修正がてらいろいろ改善を施したのでその話をしようと思う。

Control.Concurrent.Async.Lifted.Safeモジュール

v0.3.0から新たにControl.Concurrent.Async.Lifted.Safeモジュールが追加された。lifted-asyncをより安全に利用するため、既存・新規のコードにかかわらず使えるところではこちらのSafeモジュールを使い、適用できないところでのみ従来のControl.Concurrent.Async.Liftedを使うべきである。

lifted-asyncとモナドスタックのもつ副作用

そもそも以前のlifted-asyncには重大なデザイン上の欠陥があった。たとえば次のコード片は何を出力すべきだろうか。

import Control.Monad.State
import Control.Concurrent.Async.Lifted

main :: IO ()
main = do
  (r, s) <- flip runStateT 42 $ do
    a <- async $ modify (+1) >> get
    modify (+2)
    wait a
  print (r, s)

async中のmodify (+1)で状態が43になりgetで返ってくる値は43、その後さらにmodify (+2)で状態は45になり(43, 45)か？スレッド起動より先にmodify (+2)が実行され状態が44に、その後modify (+1)が実行され(45, 45)か？いやそもそも同期なしに共有状態を書き換えるのはおかしい。ではどうするべきだったのか？

現在のlifted-asyncの実装では常に(43, 43)が出力される。何故か？実装上の都合でwaitがasyncの中で起こったStateT上の副作用をすべて親スレッド側で復帰しているからである。つまりmodify (+2)は暗黙のうちに捨てられる。

どうしてこんな残念なことになっているかを理解するには実装を見てみる必要がある。asyncとwaitの実装は次の通り。

async :: MonadBaseControl IO m => m a -> m (Async (StM m a))
async m = liftBaseWith $ \runInIO -> A.async (runInIO m)

wait :: MonadBaseControl IO m => Async (StM m a) -> m a
wait = liftBase . A.wait >=> restoreM

ここでA.がついているものはasyncパッケージの関数を使っている。asyncはモナドm上の状態をStM m aという型でAsyncの中に埋め込む。waitは結果を取り出す過程でこの状態を現在のmに復帰する。もし仮にasyncでm (Async (StM m a))でなくm (Async a)を返す、またはwaitでrestoreMを使わずにaを取り出すことができれば、子スレッド中のm上の副作用はすべて無視するという戦略がとれるが、これをmについて多相的に実装する方法はないと思う。

Safeモジュール

問題の原点に立ち返ってみると、 並行処理を目的としたライブラリが状態を持つモナド上で無制限に利用可能なのがおかしい。状態を持たないモナド、すなわちStM m a ~ aを満たすモナドだけで利用できるモジュールを作ろうというのがSafeモジュールのアイデアである。

Safeモジュールではasyncとwaitの型は次のようになっている。

async :: (MonadBaseControl IO m, StM m a ~ a) => m a -> m (Async a)
wait :: (MonadBaseControl IO m, StM m a ~ a) => Async a -> m a

制約部にStM m a ~ aが追加され、この制約からAsync (StM m a) ~ Async aがいえるため、型シグネチャがasyncパッケージに近い直感的でわかりやすいものになった。実装は一部を除いてControl.Concurrent.Async.Liftedの関数をそのまま使っていて、単に型シグネチャだけ書き直している。

Safeモジュールでは先に示した副作用の問題は起こらない。なぜなら副作用が問題になるStateTなどはStM m a ~ aを満たさないため、そもそもこのモジュールを利用できないからである。現実のコードでは並行処理が必要かつ共有状態を持つモナド変換子スタックはReaderTにMVarなどを持たせているはずなのでこの制約は問題にならないことがほとんどではないかと思う。

Concurrentlyの実装上の問題

当初Safeモジュールを実装したときにConcurrentlyのApplicativeインスタンスを書くのは困難に見えた。理由はStM m a ~ aという制約はmが状態を持たないという制約であるだけでなくaがStM m aと等しくなるというようにaに対して言及しているために、aやbに何の制約も持たない(<*>) :: Applicative f => f (a -> b) -> f a -> f bと型が合わないように見えたためである。

この問題は@feuerbachさんがconstraintsパッケージを用いたすばらしい解決策を示してくれた。Concurrentlyの実装にはForall (Pure m)という制約が出てくる。これは次の擬似コード相当のことをしていると考えられる。

data Concurrently m a where
  Concurrently
    :: (forall a. (StM m a ~ a))
    => { runConcurrently :: m a } -> Concurrently m a

instance (MonadBaseControl IO m, forall a. (StM m a ~ a)) => Applicative (Concurrently m) where
  ...

つまりここで必要なStM m a ~ aという制約はmに対するもので、aはなんであってもよいはずである。しかし現在のGHCはuniversally quantifiedな制約はサポートしていないのでconstraintsパッケージを使っている。

universally quantified constraintsの使い道やconstraintsパッケージの実装の話はSafe, polykinded universally quantified constraintsというポストが詳しい。

Concurrently b m aのb

ほかにもマイナーな変更を入れた。

当初lifted-asyncにConcurrenlyを移植した際にUndecidableInstancesを嫌ってbという何もしない型変数を導入したが、これがConcurrentlyの見た目を怖くしていたようで、どうやって使うのかと質問している例をいくつか見たことがあった。 改めて見直してみるとMonadBaseControlのインスタンスで型検査をループさせることは難しそうであること、仮にそのようなインスタンスを書いてしまっても問題箇所の発見は難しくなさそうであることから、UndecidableInstancesを有効にして型変数bをなくした。先のconstraintsパッケージの影響でまた別の意味で怖い型になってしまったが、型の読みやすさという点である一定の効果はあったのではないかと思う。

今後

今のところlifted-asyncに大きな変更を加える予定はなく、地道にGHCや依存パッケージの更新に合わせてマイナーアップデートをしていくことになると思う。Haddockコメントを改善したいとは考えているけど、あまりやる気が出ないのでPR歓迎。ともあれStackageにも入っているし少しずつ利用者も出てきたようなので、モナド変換子スタックでasyncを使いたい人は是非使ってみてほしい。